RunOnceEx 做法

25/July/2010
    我將 A-Zong XP 2010 Final 的 RunOnceEx PO上來...
    與 2009 不同，我把 IE8 移到 T-12 安裝，這樣可以避免失敗
    另外我也把軟體移位，原本放在 $OEM$\$1\ 裡，現在全部移到
    Software 裡，也就是直接從光碟安裝，不用在藍色搬移資料夾
    時，還要浪費複製進去硬碟的時間，雖然安裝速度可能會稍微比
    較慢，但是這樣比較不會產生垃圾、浪費空間
--------------------------------------------------------------------------------------
    RunOnceEx 是寫在 $OEM$\Cmdlines.txt 或者寫在 I386\Winnt.sif 的 [GUIRunOnce]裡，而 RunOnceEx.cmd 主要是用來登陸 Regedit 裡面的 HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\RunOnceEx，他會在第一次開機未載入 GUI 前執行。
--------------------------------------------------------------------------------------
Cmdlines.txt 寫法 (A-Zong XP 用的方法)：
    在底下加入 "RunOnceEx.cmd" ←含引號
    並與 Cmdlines.txt 放在同一層目錄
--------------------------------------------------------------------------------------
以下為 A-Zong 2010 Final 所寫的：

cmdow @ /HID
REM cmdow 可以隱藏視窗，必須要另外裝！可以把它放在 $OEM$\$$\System32 裡
REM 這樣就會再安裝自動複製進去

@echo off

set tagfile=\WIN51

FOR %%i IN (D E F G H I J K L M N O P Q R S T U V W X Y Z) DO IF EXIST "%%i:%tagfile%" set CDROM=%%i:
REM 以上是用來判斷 CD-ROM 的位置


SET KEY=HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\RunOnceEx
REM 以上是為了縮短以下的字數

REG ADD %KEY% /V TITLE /D "A-Zong XP 2010" /f
REM 這是標題

REG ADD %KEY%\010 /VE /D "DriverPacks" /f
REG ADD %KEY%\010 /V 1 /D "%SystemDrive%\DPsFnshr.exe" /f

REG ADD %KEY%\020 /VE /D "偽‧XP SP4" /f
REG ADD %KEY%\020 /V 1 /D "%CDROM%\Software\RunOnceEx\wxp_sp4\hotfix.cmd" /f

REG ADD %KEY%\030 /VE /D ".Net Framework" /f
REG ADD %KEY%\030 /V 1 /D "%CDROM%\Software\RunOnceEx\netfx\setup.cmd" /f

REG ADD %KEY%\040 /VE /D "DirectX 9.0c" /f
REG ADD %KEY%\040 /V 1 /D "%CDROM%\Software\RunOnceEx\DirectX\2009_Mar\DXSETUP.exe /silent" /f

REG ADD %KEY%\050 /VE /D "Silverlight 3.0" /f
REG ADD %KEY%\050 /V 1 /D "%CDROM%\Software\RunOnceEx\Silverlight\Silverlight.exe /q" /f

REG ADD %KEY%\060 /VE /D "piapi AppLocale" /f
REG ADD %KEY%\060 /V 1 /D "%CDROM%\Software\RunOnceEx\AppLocale\setup.cmd" /f

REG ADD %KEY%\070 /VE /D "軟體選單" /f
REG ADD %KEY%\070 /V 1 /D "%CDROM%\WPI\WPI.cmd " /f
REG ADD %KEY%\070 /V 2 /D "%CDROM%\Software\RunOnceEx\finish.cmd" /f

REM 以下為簡說...
REM REG ADD %KEY% /V TITLE /D "總標題" /f
REM REG ADD %KEY%\(數字a) /VE /D "各項目標題" /f
REM REG ADD %KEY%\(數字a) /V (第1項) /D "欲執行的命令" /f
REM                                          ：
REM REG ADD %KEY%\(數字a) /V (第n項) /D "欲執行的命令" /f
REM 更多的指令請參考 reg /?

EXIT